How to Use Excel VBA to Paste Range into Email Body (3 Methods)

If you are working with an Excel worksheet that you need to update and share with other people via email on a frequent basis, VBA macro in Excel can reduce the hassle of sending the file repeatedly with a single click. In this tutorial, I will show you how to use Excel VBA to paste range into the email body without even having to open your mail inbox or app.

Use Excel VBA to Paste Range into Email Body: 3 Methods

Let’s assume a scenario where we have an Excel file that contains information about the employees of a company. The worksheet has the Name, Age, Gender, Date of Birth, and the State each of them comes from. We will copy and then paste the range of this worksheet into the email body using VBA. The image below shows the range from the worksheet that we have pasted into the email body.

Method 1: Paste Range as Image into Email Body Using VBA in Excel

Step 1:

• First, we have to log in to our Outlook mail app. None of the VBA codes here will work if you do not use Outlook as the mail app. So, we will first log in to the Outlook app. Insert your email address in the input box of the app and click on Connect just like the image below.

Step 2:

• We will now select the cell range that we want to paste into the email body. We have selected the entire data range of the worksheet.

• Now, we will select Visual Basic from the Developer. We can also press ALT+F11 to open it.

• Now, click on the Insert button and select Module.

• Then, write down the following code in the window that appears.

Sub Paste_Range_Outlook()
    Dim rng As Range
    Dim Outlook As Object
    Dim OutlookMail As Object
    Set rng = Nothing
    On Error Resume Next
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
    If rng Is Nothing Then
        MsgBox "Not a range or protected sheet" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    Set Outlook = CreateObject("Outlook.Application")
    Set OutlookMail = Outlook.CreateItem(0)
    On Error Resume Next
    With OutlookMail
        .To = ""
        .CC = ""
        .BCC = ""
        .Subject = "Excel Data you requested for"
        .HTMLBody = RangetoHTML(rng)
        .Display   'or use .Send
    End With
    On Error GoTo 0
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
    Set OutlookMail = Nothing
    Set Outlook = Nothing
End Sub
Function RangetoHTML(rng As Range)
    Dim obj As Object
    Dim txtstr As Object
    Dim File As String
    Dim WB As Workbook
    File = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
    rng.Copy
    Set WB = Workbooks.Add(1)
    With WB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
    With WB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         FileName:=File, _
         Sheet:=WB.Sheets(1).Name, _
         Source:=WB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
    Set obj = CreateObject("Scripting.FileSystemObject")
    Set txtstr = obj.GetFile(File).OpenAsTextStream(1, -2)
    RangetoHTML = txtstr.readall
    txtstr.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
    WB.Close savechanges:=False
    Kill File
    Set txtstr = Nothing
    Set obj = Nothing
    Set WB = Nothing
End Function

• Now, click on the Run (▶).

• If a window named Macro appears, just click on Run from that window.

• Finally, we will see that a window of the Outlook mail app appears with a new mail that has the entire range we have copied from the worksheet in its body.

Read More: How to Send Email from Excel with Body Using a Macro

Method 2: Use VBA to Copy and Paste Range as Image into Email

Alternatively, we can also copy and paste the range as an image format into the mail body. Let’s see how we can do that.

Step 1:

• First, we will insert a new Module.

Step 2:

• Then, we will write down the following code in the window that appears.

Sub PasteRangeinMail()
Dim FilePath As String
Dim Outlook As Object
Dim OutlookMail As Object
Dim HTMLBody As String
Dim rng As Range
On Error Resume Next
Set rng = Selection
If rng Is Nothing Then Exit Sub
With Application
.Calculation = xlManual
.ScreenUpdating = False
.EnableEvents = False
End With
Set Outlook = CreateObject("outlook.application")
Set OutlookMail = Outlook.CreateItem(olMailItem)
Call createImage(ActiveSheet.Name, rng.Address, "RangeImage")
FilePath = Environ$("temp") & "\"
HTMLBody = "<span LANG=EN>" _
& "<p class=style1><span LANG=EN><font FACE=Times New Roman SIZE=4>" _
& "Dear Concerned," _
& "<br>" _
& "This is the Excel data you requested for:<br> " _
& "<br>" _
& "<img src='cid:RangeImage.jpg'>" _
& "<br>" _
& "<br>Kind Regards!!!!!</font></span>"
With OutlookMail
.Subject = ""
.HTMLBody = HTMLBody
.Attachments.Add FilePath & "RangeImage.jpg", olByValue
.To = "[email protected]"
.CC = " "
.Display
End With
End Sub
Sub createImage(SheetName As String, rngAddrss As String, nameFile As String)
Dim rngJpg As Range
Dim Shape As Shape
ThisWorkbook.Activate
Worksheets(SheetName).Activate
Set rngJpg = ThisWorkbook.Worksheets(SheetName).Range(rngAddrss)
rngJpg.CopyPicture
With ThisWorkbook.Worksheets(SheetName).ChartObjects.Add(rngJpg.Left, rngJpg.Top, rngJpg.Width, rngJpg.Height)
.Activate
For Each Shape In ActiveSheet.Shapes
Shape.Line.Visible = msoFalse
Next
.Chart.Paste
.Chart.Export Environ$("temp") & "\" & nameFile & ".jpg", "JPG"
End With
Worksheets(SheetName).ChartObjects(Worksheets(SheetName).ChartObjects.Count).Delete
Set rngJpg = Nothing
End Sub

• Now, click on the Run (▶).

• If a window named Macro appears, just click on Run from that window.

• Finally, we will see that a window of the Outlook mail app appears with a new mail that has the entire range we have copied from the worksheet as a jpg image in its body.

Read More: VBA to Generate Multiple Lines in Email Body in Excel

Method 3: Copy Ranges From Multiple Worksheets and Paste as Images into Email Using VBA

We can also copy multiple ranges from different worksheets and then paste them as images into the body of an email using VBA. We have to do the following.

Step 1:

• First, we will select the ranges we want to paste into the body of an email. We have chosen the ranges under the Gender and Date of Birth columns from the first worksheet.

• Then, we selected the range under the Name column from the second worksheet.

Step 2:

• Then, we will write down the following code in the window that appears.

Sub PasteMultipleRangeinMail()
Dim FilePath As String
Dim Outlook As Object
Dim OutlookMail As Object
Dim HTMLBody As String
Dim rng As Range
Dim Sheet As Worksheet
Dim AcSheet As Worksheet
Dim FileName As String
Dim Src As String
On Error Resume Next
FilePath = Environ$("temp") & "\RangeImage\"
If Len(VBA.Dir(FilePath, vbDirectory)) = False Then
VBA.MkDir FilePath
End If
Set AcSheet = Application.ActiveSheet
For Each Sheet In Application.Worksheets
Sheet.Activate
Set rng = Sheet.Application.Selection
If rng.Cells.Count > 1 Then
Call createJpg(Sheet.Name, rng.Address, "DashboardFile" & VBA.Trim(VBA.Str(Sheet.Index)))
End If
Next
AcSheet.Activate
With Application
.Calculation = xlManual
.ScreenUpdating = False
.EnableEvents = False
End With
Set Outlook = CreateObject("outlook.application")
Set OutlookMail = Outlook.CreateItem(olMailItem)
Src = ""
FileName = Dir(FilePath & "*.*")
Do While FileName <> ""
Src = Src + VBA.vbCrLf + "<img src='cid:" + FileName + "'><br>"
FileName = Dir
If FileName = "" Then Exit Do
Loop
HTMLBody = "<span LANG=EN>" _
& "<p class=style1><span LANG=EN><font FACE=Times New Roman SIZE=4>" _
& "Dear Concerned," _
& "<br>" _
& "This is the Excel data you requested for:<br> " _
& "<br>" _
& Src _
& "<br>Best Regards!</font></span>"
With OutlookMail
.Subject = ""
.HTMLBody = HTMLBody
FileName = Dir(FilePath & "*.*")
Do While FileName <> ""
.Attachments.Add FilePath & FileName, olByValue
FileName = Dir
If FileName = "" Then Exit Do
Loop
.To = " "
.CC = " "
.Display
End With
If VBA.Dir(FilePath & "*.*") <> "" Then
VBA.Kill FilePath & "*.*"
End If
End Sub
Sub createJpg(SheetName As String, rngAddrss As String, nameFile As String)
Dim rngPic As Range
ThisWorkbook.Activate
Worksheets(SheetName).Activate
Set rngPic = ThisWorkbook.Worksheets(SheetName).Range(rngAddrss)
rngPic.CopyPicture
With ThisWorkbook.Worksheets(SheetName).ChartObjects.Add(rngPic.Left, rngPic.Top, rngPic.Width, rngPic.Height)
.Activate
.Chart.Paste
.Chart.Export Environ$("temp") & "\RangeImage\" & nameFile & ".jpg", "JPG"
End With
Worksheets(SheetName).ChartObjects(Worksheets(SheetName).ChartObjects.Count).Delete
Set rngPic = Nothing
End Sub

• Now, click on the Run (▶).

Step 3:

• If a window named Macro appears, just click on Run from that window.

• Finally, we will see that a window of the Outlook mail app appears with a new mail that has the ranges we have copied from the worksheet as separate jpg images in its body.

Read More: Macro to Send Email from Excel

Quick Notes

• You should have the Outlook mail app to paste the range into the email body using VBA.
• If you do not have a Developer tab, you can make it visible in File > Option > Customize Ribbon.
• To open the VBA editor Press ALT + F11. You can press ALT + F8 to bring up the Macro window.

Download Practice Workbook

Download this practice book to exercise the task while you are reading this article.

Conclusion

In this article, we have learned how to use Excel VBA to paste range into the email body. I hope from now on you can use Excel VBA to paste range into the email body very easily. However, if you have any queries or recommendations about this article, please do leave a comment below. Have a great day!!!

Related Articles

• Send Reminder Email Automatically from an Excel Worksheet Using VBA
• Send Email from Excel VBA without Outlook
  
• How to Apply Macro to Send Email from Excel with Attachment
• Excel Macro to Send Email Automatically
• Excel Macro: Send Email to an Address in Cell
• Print to PDF and Email Using VBA in Excel